Program Heidenhain TNC640

Witam

Jestem totalnym laikiem jeśli chodzi o jakiekolwiek obrabiarki CNC i przychodzę tutaj z prośbą o małą pomoc bardziej doświadczonych osób

Mam taki rysunek i muszę do niego napisać program w symulatorze obrabiarki:

TNC 640 Programming Station Software 340595-04 SP6
With virtualization software (VirtualBox)

Załączam zdjęcie szkicu technologicznego

Byłbym bardzo wdzięczny za pomoc

Pozdrawiam

A podstawy jakieś masz? czy nic nie ogarniasz?
Jeśli nic, to że ktoś ci napisze program to nic z niego nie zrozumiesz.

Podstawy z instrukcji użytkownika mam i zajmuję się programowaniem ogólnym w java, python czy sql szybko się uczę

Podstawa to materiał, kształt i rozmiar przygotówki bo bez tego to najwyżej wzór na kolizję można napisać

Po 3 dniach pewnie już poradziłeś sobie z problemem ale i tak masz tu program oczywiście parametry są totalnie z kosmosu bo i tak chcesz to tylko do symulatora a symulator łyknie wszystko
Program:
0 BEGIN PGM KOSTKA MM
1 BLK FORM 0.1 Z X-50 Y+0 Z-15
2 BLK FORM 0.2 X+0 Y+40 Z+0
3 TOOL CALL 222 Z S1111 ;NAWIERTAK FI2
4 CYCL DEF 200 WIERCENIE ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q201=-1 ;GLEBOKOSC ~
Q206=+40 ;WARTOSC POSUWU WGL. ~
Q202=+5 ;GLEBOKOSC DOSUWU ~
Q210=+0 ;PRZER. CZAS.NA GORZE ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+30 ;2-GA BEZPIECZNA WYS. ~
Q211=+1 ;PRZERWA CZAS. DNIE ~
Q395=+0 ;REFERENCJA GLEB.
5 LBL 1
6 L X-5.5 Y+5.5 R0 FMAX M99 M3 M8
7 L X-44.5 Y+5.5 R0 FMAX M99
8 LBL 0
9 LBL 2
10 L X-42 Y+32 R0 FMAX M3 M8 M99
11 LBL 0
12 LBL 3
13 L X-15 Y+25 R0 FMAX M99 M3 M8
14 LBL 0
15 TOOL CALL 228 Z S1111 ;WIERTLO FI6
16 CYCL DEF 205 WIERCENIE GLEB.UNIW. ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q201=-19 ;GLEBOKOSC ~
Q206=+40 ;WARTOSC POSUWU WGL. ~
Q202=+5 ;GLEBOKOSC DOSUWU ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+30 ;2-GA BEZPIECZNA WYS. ~
Q212=+0 ;WART. ZMNIEJ. DOSUWU ~
Q205=+0 ;MIN. GLEBOK. DOSUWU ~
Q258=+0.2 ;ODSTEP WYPRZ.U GORY ~
Q259=+0.2 ;ODSTEP WYPRZ. U DOLU ~
Q257=+0.5 ;GLEB. LAMANIA WIORA ~
Q256=+0.2 ;POW.PRZY LAMAN.WIORA ~
Q211=+0 ;PRZERWA CZAS. DNIE ~
Q379=+0 ;PUNKT STARTU ~
Q253=+750 ;PREDK. POS. ZAGLEB. ~
Q208=+99999 ;POSUW RUCHU POWROTN. ~
Q395=+0 ;REFERENCJA GLEB.
17 CALL LBL 1
18 CALL LBL 2
19 TOOL CALL 235 Z S1111 ;WIERTLO FI 16
20 CYCL DEF 205 WIERCENIE GLEB.UNIW. ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q201=-22 ;GLEBOKOSC ~
Q206=+40 ;WARTOSC POSUWU WGL. ~
Q202=+5 ;GLEBOKOSC DOSUWU ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+30 ;2-GA BEZPIECZNA WYS. ~
Q212=+0 ;WART. ZMNIEJ. DOSUWU ~
Q205=+0 ;MIN. GLEBOK. DOSUWU ~
Q258=+0.2 ;ODSTEP WYPRZ.U GORY ~
Q259=+0.2 ;ODSTEP WYPRZ. U DOLU ~
Q257=+0.5 ;GLEB. LAMANIA WIORA ~
Q256=+0.2 ;POW.PRZY LAMAN.WIORA ~
Q211=+0 ;PRZERWA CZAS. DNIE ~
Q379=+0 ;PUNKT STARTU ~
Q253=+750 ;PREDK. POS. ZAGLEB. ~
Q208=+99999 ;POSUW RUCHU POWROTN. ~
Q395=+0 ;REFERENCJA GLEB.
21 CALL LBL 3
22 TOOL CALL 2 Z S1111 ;FREZ FI 4
23 CYCL DEF 252 WYBRANIE KOLOWE ~
Q215=+0 ;RODZAJ OBROBKI ~
Q223=+12 ;SREDNICA OKREGU ~
Q368=+0.1 ;NADDATEK NA STRONE ~
Q207=+450 ;POSUW FREZOWANIA ~
Q351=+1 ;RODZAJ FREZOWANIA ~
Q201=-7 ;GLEBOKOSC ~
Q202=+7 ;GLEBOKOSC DOSUWU ~
Q369=+0.1 ;NADDATEK NA DNIE ~
Q206=+300 ;WARTOSC POSUWU WGL. ~
Q338=+0 ;DOSUW - OBR.WYKONCZ. ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+30 ;2-GA BEZPIECZNA WYS. ~
Q370=+0.2 ;ZACHODZENIE TOROW ~
Q366=+0 ;ZAGLEBIANIE ~
Q385=+200 ;POSUW OBR.WYKAN. ~
Q439=+0 ;BAZA POSUWU
24 CALL LBL 2
25 CYCL DEF 233 FREZOWANIE PLANOWE ~
Q215=+0 ;RODZAJ OBROBKI ~
Q389=+2 ;STRATEGIA FREZOWANIA ~
Q350=+2 ;KIERUNEK FREZOWANIA ~
Q218=-11.5 ;DLUG. 1-SZEJ STRONY ~
Q219=-11.5 ;DLUG. 2-GIEJ STRONY ~
Q227=+0 ;PKT.STARTU 3CIEJ OSI ~
Q386=-7 ;PUNKT KONCOWY 3. OSI ~
Q369=+0.1 ;NADDATEK NA DNIE ~
Q202=+7 ;MAX. GLEB. DOSUWU ~
Q370=+0.2 ;ZACHODZENIE TOROW ~
Q207=+450 ;POSUW FREZOWANIA ~
Q385=+200 ;POSUW OBR.WYKAN. ~
Q253= MAX ;PREDK. POS. ZAGLEB. ~
Q357=+2 ;ODST. BEZP. Z BOKU ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q204=+30 ;2-GA BEZPIECZNA WYS. ~
Q347=-1 ;1.LIMIT ~
Q348=+2 ;2.LIMIT ~
Q349=+0 ;3.LIMIT ~
Q220=+6 ;PROMIEN NAROZA ~
Q368=+0.1 ;NADDATEK NA STRONE ~
Q338=+0 ;DOSUW - OBR.WYKONCZ.
26 L X+0 Y+11.5 R0 FMAX M99
27 CYCL DEF 233 FREZOWANIE PLANOWE ~
Q215=+0 ;RODZAJ OBROBKI ~
Q389=+2 ;STRATEGIA FREZOWANIA ~
Q350=+2 ;KIERUNEK FREZOWANIA ~
Q218=+11.5 ;DLUG. 1-SZEJ STRONY ~
Q219=+11.5 ;DLUG. 2-GIEJ STRONY ~
Q227=+0 ;PKT.STARTU 3CIEJ OSI ~
Q386=-7 ;PUNKT KONCOWY 3. OSI ~
Q369=+0.1 ;NADDATEK NA DNIE ~
Q202=+7 ;MAX. GLEB. DOSUWU ~
Q370=+0.2 ;ZACHODZENIE TOROW ~
Q207=+450 ;POSUW FREZOWANIA ~
Q385=+200 ;POSUW OBR.WYKAN. ~
Q253= MAX ;PREDK. POS. ZAGLEB. ~
Q357=+2 ;ODST. BEZP. Z BOKU ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q204=+30 ;2-GA BEZPIECZNA WYS. ~
Q347=+1 ;1.LIMIT ~
Q348=+2 ;2.LIMIT ~
Q349=+0 ;3.LIMIT ~
Q220=+6 ;PROMIEN NAROZA ~
Q368=+0.1 ;NADDATEK NA STRONE ~
Q338=+0 ;DOSUW - OBR.WYKONCZ.
28 L X-50 Y+0 R0 FMAX M99
29 TOOL CALL 5 Z S1111 ;FREZ FI 10
30 CYCL DEF 252 WYBRANIE KOLOWE ~
Q215=+0 ;RODZAJ OBROBKI ~
Q223=+20.15 ;SREDNICA OKREGU ~
Q368=+0.1 ;NADDATEK NA STRONE ~
Q207=+450 ;POSUW FREZOWANIA ~
Q351=+1 ;RODZAJ FREZOWANIA ~
Q201=-16 ;GLEBOKOSC ~
Q202=+16 ;GLEBOKOSC DOSUWU ~
Q369=+0 ;NADDATEK NA DNIE ~
Q206=+300 ;WARTOSC POSUWU WGL. ~
Q338=+0 ;DOSUW - OBR.WYKONCZ. ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+30 ;2-GA BEZPIECZNA WYS. ~
Q370=+0.2 ;ZACHODZENIE TOROW ~
Q366=+0 ;ZAGLEBIANIE ~
Q385=+200 ;POSUW OBR.WYKAN. ~
Q439=+0 ;BAZA POSUWU
31 CALL LBL 3
32 L Z+100 R0 FMAX
33 ;ODJAZD OD MATERIALU ALE TO CO MASZYNA TO INNE WSPOLRZEDNE
34 M30
35 END PGM KOSTKA MM
Oczywiście jest to jeden z wielu sposobów napisania tego detalu ale chyba jest to jeden z najprostszych
(wyszedłem z założenia że masz już gotowy gabaryt)

Tutaj niżej zamieszczam program napisany w troszkę inny sposób niż wyżej, pozdrawiam.





0 BEGIN PGM xyz MM
1 BLK FORM 0.1 Z X-50 Y+0 Z-15
2 BLK FORM 0.2 X+0 Y+40 Z+0
3 CYCL DEF 247 USTAWIENIE PKT.BAZ ~
Q339=+1 ;NR PKT BAZOWEGO
4 ;
5 * - WYBRANIA 11.5
6 TOOL CALL 6 Z S2750 ;FREZ FI12
7 L Z+200 FMAX M3
8 L X+10 Y-10 FMAX
9 L Z+0 FMAX
10 LBL 1
11 L IZ-3.5 FMAX
12 L Y+11.5 RL F500
13 L X-11.5
14 L Y-10
15 L X+10 Y-10 R0 FMAX
16 CALL LBL 1 REP1
17 L Z+200 FMAX
18 L X-60 Y-10 FMAX
19 L Z+0 FMAX
20 LBL 2
21 L IZ-3.5 FMAX
22 L X-38.5 RL F500
23 L Y+11.5
24 L X-60
25 L X-60 Y-10 R0 FMAX
26 CALL LBL 2 REP1
27 L Z+200 FMAX
28 ;
29 * - POGLEBIENIE FI12
30 TOOL CALL 4 Z S3800 ;FREZ FI8
31 L Z+200 FMAX M3
32 L X-42 Y+32 FMAX
33 CYCL DEF 208 SPIRALNE FREZ. OTW. ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q201=-7 ;GLEBOKOSC ~
Q206=+350 ;WARTOSC POSUWU WGL. ~
Q334=+1 ;GLEBOKOSC DOSUWU ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+150 ;2-GA BEZPIECZNA WYS. ~
Q335=+12 ;SREDNICA NOMINALNA ~
Q342=+1 ;WYW.WSTEP. SREDNICA ~
Q351=+1 ;RODZAJ FREZOWANIA
34 CYCL CALL
35 ;
36 * - NAWIERCANIE FI6
37 TOOL CALL 2 Z S1600 ;Nawiertak
38 CYCL DEF 200 WIERCENIE ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q201=-2 ;GLEBOKOSC ~
Q206=+150 ;WARTOSC POSUWU WGL. ~
Q202=+3 ;GLEBOKOSC DOSUWU ~
Q210=+0 ;PRZER. CZAS.NA GORZE ~
Q203=-7 ;WSPOLRZEDNE POWIERZ. ~
Q204=+150 ;2-GA BEZPIECZNA WYS. ~
Q211=+0 ;PRZERWA CZAS. DNIE ~
Q395=+0 ;REFERENCJA GLEB.
39 CALL LBL 10
40 ;
41 * - NAWIERCANIE FI20
42 TOOL CALL 2 Z S1600 ;Nawiertak
43 CYCL DEF 200 WIERCENIE ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q201=-2 ;GLEBOKOSC ~
Q206=+150 ;WARTOSC POSUWU WGL. ~
Q202=+3 ;GLEBOKOSC DOSUWU ~
Q210=+0 ;PRZER. CZAS.NA GORZE ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+150 ;2-GA BEZPIECZNA WYS. ~
Q211=+0 ;PRZERWA CZAS. DNIE ~
Q395=+0 ;REFERENCJA GLEB.
44 CALL LBL 20
45 ;
46 * - WIERCENIE FI6
47 TOOL CALL 3 Z S1000 ;WIERTLO FI6
48 CYCL DEF 200 WIERCENIE ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q201=-12 ;GLEBOKOSC ~
Q206=+150 ;WARTOSC POSUWU WGL. ~
Q202=+3 ;GLEBOKOSC DOSUWU ~
Q210=+0 ;PRZER. CZAS.NA GORZE ~
Q203=-7 ;WSPOLRZEDNE POWIERZ. ~
Q204=+150 ;2-GA BEZPIECZNA WYS. ~
Q211=+0 ;PRZERWA CZAS. DNIE ~
Q395=+0 ;REFERENCJA GLEB.
49 CALL LBL 10
50 ;
51 * - WIERCENIE WSTEPNE FI20
52 TOOL CALL 6 Z S530 ;WIERTLO FI12
53 CYCL DEF 200 WIERCENIE ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q201=-20 ;GLEBOKOSC ~
Q206=+85 ;WARTOSC POSUWU WGL. ~
Q202=+3 ;GLEBOKOSC DOSUWU ~
Q210=+0 ;PRZER. CZAS.NA GORZE ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+150 ;2-GA BEZPIECZNA WYS. ~
Q211=+0 ;PRZERWA CZAS. DNIE ~
Q395=+0 ;REFERENCJA GLEB.
54 CALL LBL 20
55 ;
56 * - FREZOWANIE FI20
57 TOOL CALL 6 Z S2750
58 CYCL DEF 208 SPIRALNE FREZ. OTW. ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q201=-16 ;GLEBOKOSC ~
Q206=+500 ;WARTOSC POSUWU WGL. ~
Q334=+1 ;GLEBOKOSC DOSUWU ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+150 ;2-GA BEZPIECZNA WYS. ~
Q335=+20 ;SREDNICA NOMINALNA ~
Q342=+10 ;WYW.WSTEP. SREDNICA ~
Q351=+1 ;RODZAJ FREZOWANIA
59 CALL LBL 20
60 ;
61 M2 ;KONIEC PROGRAMU
62 ;
63 LBL 10
64 L Z+200 FMAX M3
65 L X-5.5 Y+5.5 FMAX M99
66 L X-45 FMAX M99
67 L X-42 Y+32 FMAX M99
68 LBL 0
69 ;
70 LBL 20
71 L Z+200 FMAX M3
72 L X-15 Y+25 FMAX M99
73 LBL 0
74 END PGM xyz MM