Problem z cyklami 215 i 267

martinprz · Post napisał: **martinprz** » 08 wrz 2011, 22:50

Witam,
Czy moglibyście sprawdzić i poprawić mi cykle do frezowania czopa okrągłego 215 i do frezowania gwintu zewnętrznego (czy tutaj w tablicy narzędzi należy wpisać tylko średnicę narzędzia i skok gwintu?). Jak widać na rysunku cykl 215 jest wykonywany częściowo a cykl 267 w ogóle nie jest wykonywany.

0 BEGIN PGM goo 7 MM
1 BLK FORM 0.1 Z X-26 Y-22 Z-20
2 BLK FORM 0.2 X+26 Y+22 Z+25
3 TOOL CALL 16 Z S3000
4 ;frez fi 20
5 CYCL DEF 215 WYSEP.KOL.NA GOT. ~
Q200=+5 ;BEZPIECZNA WYSOKOSC ~
Q201=+0 ;GLEBOKOSC ~
Q206=+150 ;WARTOSC POSUWU WGL. ~
Q202=+5 ;GLEBOKOSC DOSUWU ~
Q207=+500 ;POSUW FREZOWANIA ~
Q203=-25 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS. ~
Q216=+0 ;SRODEK W 1-SZEJ OSI ~
Q217=+0 ;SRODEK W 2-SZEJ OSI ~
Q222=+80 ;SREDNICA WST.OBR.WYB ~
Q223=+20 ;SRED.WYBR.OBR.NA GOT
6 CYCL CALL POS X+0 Y+0 Z+0 FMAX M3 M8
7 L Z+200 R0 FMAX M9 M6
8 TOOL CALL 20 Z S3000
9 ;FREZ DO GWINTU M20X1.5
10 CYCL DEF 267 FREZOW. GWINTU ZEWN. ~
Q335=+20 ;SREDNICA NOMINALNA ~
Q239=+1.5 ;SKOK ~
Q201=-20 ;GLEBOKOSC GWINTU ~
Q355=+1 ;ILOSC KROKOW DO WYK. ~
Q253=+750 ;PREDK. POS. ZAGLEB. ~
Q351=+1 ;RODZAJ FREZOWANIA ~
Q200=+5 ;BEZPIECZNA WYSOKOSC ~
Q358=+0 ;GLEB. STRONA CZOLOWA ~
Q359=+0 ;PRZES. NA STR. CZOL. ~
Q203=+25 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS. ~
Q254=+200 ;PREDK. POS. POGLEB. ~
Q207=+500 ;POSUW FREZOWANIA
11 CYCL CALL POS X+0 Y+0 Z+0 F4000 M3 M8
12 L Z+200 R0 FMAX M9 M6
13 M2
14 END PGM goo 7 MM

Za pomoc będę bardzo wdzięczny

martinprz

barcel · Post napisał: **barcel** » 09 wrz 2011, 09:54

0 BEGIN PGM goo 7 MM
1 BLK FORM 0.1 Z X-26 Y-22 Z-20
2 BLK FORM 0.2 X+26 Y+22 Z+25
3 TOOL CALL 16 Z S3000
4 ;frez fi 20
L X+0 Y+0 FMAX M13
L Z+30 FMAX
5 CYCL DEF 215 WYSEP.KOL.NA GOT. ~
Q200=+30 ;BEZPIECZNA WYSOKOSC ~
Q201=+0 ;GLEBOKOSC ~
Q206=+150 ;WARTOSC POSUWU WGL. ~
Q202=+5 ;GLEBOKOSC DOSUWU ~
Q207=+500 ;POSUW FREZOWANIA ~
Q203=+25 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS. ~
Q216=+0 ;SRODEK W 1-SZEJ OSI ~
Q217=+0 ;SRODEK W 2-SZEJ OSI ~
Q222=+25 ;SREDNICA WST.OBR.WYB ~
Q223=+20 ;SRED.WYBR.OBR.NA GOT
6 L X+0 Y+0 FMAX M99
7 L Z+200 R0 FMAX M9 M6

8 TOOL CALL 20 Z S3000
9 ;FREZ DO GWINTU M20X1.5
L X+0 Y+0 FMAX M13
L Z+30 FMAX
10 CYCL DEF 267 FREZOW. GWINTU ZEWN. ~
Q335=+20 ;SREDNICA NOMINALNA ~
Q239=+1.5 ;SKOK ~
Q201=-20 ;GLEBOKOSC GWINTU ~
Q355=+1 ;ILOSC KROKOW DO WYK. ~
Q253=+750 ;PREDK. POS. ZAGLEB. ~
Q351=+1 ;RODZAJ FREZOWANIA ~
Q200=+30 ;BEZPIECZNA WYSOKOSC ~
Q358=+0 ;GLEB. STRONA CZOLOWA ~
Q359=+0 ;PRZES. NA STR. CZOL. ~
Q203=+25 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS. ~
Q254=+200 ;PREDK. POS. POGLEB. ~
Q207=+500 ;POSUW FREZOWANIA
11 L X+0 Y+0 FMAX M99
12 L Z+200 R0 FMAX M9 M6
13 M2
14 END PGM goo 7 MM

MOŻE TAK ??

MECO · Post napisał: **MECO** » 09 wrz 2011, 17:42

Cykl gwintowania jest wykonywany natomiast cykl 215 nie jest wykonywany,dlaczego?
Głebokość 0 ? niema takiej głębokości może być -0.01,-0.001 lub więcej ale NIE 0. Jak poprawisz głębokość i zmienisz współrzędną pow. z -25 na 0 to zadziała. Co do cyklu 267,nie używałem go.W tabeli narz.podajesz tylko średnice narzędzia no i oczywiście długość a skok gwintu określasz w cyklu.

martinprz · Post napisał: **martinprz** » 10 wrz 2011, 00:06

Barcel i Meco poprawiłem program jak poniżej, jednak nadal w symulacji mam ten sam efekt:( Nie widzę np. frezowania gwintu i są pozostałości na rogach kostki. Może pokazalibyście zrzuty z symulacji jak u Was ona wygląda?

0 BEGIN PGM goo 7 MM
1 BLK FORM 0.1 Z X-26 Y-22 Z-20
2 BLK FORM 0.2 X+26 Y+22 Z+25
3 TOOL CALL 16 Z S3000
4 ;frez fi 20
5 CYCL DEF 215 WYSEP.KOL.NA GOT. ~
Q200=+5 ;BEZPIECZNA WYSOKOSC ~
Q201=+0 ;GLEBOKOSC ~
Q206=+150 ;WARTOSC POSUWU WGL. ~
Q202=+5 ;GLEBOKOSC DOSUWU ~
Q207=+500 ;POSUW FREZOWANIA ~
Q203=+25 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS. ~
Q216=+0 ;SRODEK W 1-SZEJ OSI ~
Q217=+0 ;SRODEK W 2-SZEJ OSI ~
Q222=+25 ;SREDNICA WST.OBR.WYB ~
Q223=+20 ;SRED.WYBR.OBR.NA GOT
6 CYCL CALL POS X+0 Y+0 Z+0 FMAX M3 M8
7 L Z+200 R0 FMAX M9 M6
8 TOOL CALL 20 Z S3000
9 ;FREZ DO GWINTU M20X1.5
10 CYCL DEF 267 FREZOW. GWINTU ZEWN. ~
Q335=+20 ;SREDNICA NOMINALNA ~
Q239=+1.5 ;SKOK ~
Q201=-20 ;GLEBOKOSC GWINTU ~
Q355=+1 ;ILOSC KROKOW DO WYK. ~
Q253=+750 ;PREDK. POS. ZAGLEB. ~
Q351=+1 ;RODZAJ FREZOWANIA ~
Q200=+10 ;BEZPIECZNA WYSOKOSC ~
Q358=+0 ;GLEB. STRONA CZOLOWA ~
Q359=+0 ;PRZES. NA STR. CZOL. ~
Q203=+25 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS. ~
Q254=+200 ;PREDK. POS. POGLEB. ~
Q207=+500 ;POSUW FREZOWANIA
11 CYCL CALL POS X+0 Y+0 Z+0 F4000 M3 M8
12 L Z+200 R0 FMAX M9 M6
13 M2
14 END PGM goo 7 MM

Post napisał: **WZÓR** » 10 wrz 2011, 10:09

martinprz pisze:... Jak widać na rysunku cykl 215 jest wykonywany częściowo a cykl 267 w ogóle nie jest wykonywany.

Poszerz zakres pracy freza w prostokącie o wymiarach 44mm/52mm o wartość jego promienia , to usuniesz nieobrobione naroża.
.... nad gwintem pracuję jeszcze .

Obrazek

0 BEGIN PGM przykład MM
1 BLK FORM 0.1 Z X+0 Y+0 Z-100
2 BLK FORM 0.2 X+100 Y+100 Z+0
3 TOOL CALL 6 Z S500
4 L X+33. Y+28. FMAX M3
5 L Z+25. R0 FMAX M8
6 L Z+2.5 FMAX
7 L Z-25. F160.
8 L X+32. RL F320.
9 L Y-28.
10 L X-32.
11 L Y+28.
12 L X-9.798
13 L Y+23.
14 CC X+0 Y+0
15 C X-9.798 Y-23. DR+ F320.
16 L X-27.
17 L Y+23.
18 L X-9.798
19 L Y+28.
20 L X+32.
21 L X+27. Y+23.
22 L Y-23.
23 L X+9.798
24 CC X+0 Y+0
25 C X+25. Y+0 DR+ F320.
26 CC X+0 Y+0
27 C X+9.798 Y+23. DR+ F320.
28 L X+27.
29 L Y+24. R0
30 L X+19.792 Y+16.86
31 L X+15.225 Y+12.969 RL
32 CC X+0 Y+0
33 C X+20. Y+0 DR- F320.
34 CC X+0 Y+0
35 C X+15.225 Y+12.969 DR- F320.
36 L X+15.986 Y+13.618 R0
37 L Z+25. FMAX
38 L R0 FMAX
39 M9
40 M5
41 M30
42 END PGM przykład MM

ciekavy · Post napisał: **ciekavy** » 10 wrz 2011, 10:39

Kod: Zaznacz cały

0  BEGIN PGM gwint MM 
1  BLK FORM 0.1 Z  X-26  Y-22  Z-20
2  BLK FORM 0.2  X+26  Y+22  Z+25
3  TOOL CALL 16 Z S3000
4  ;frez fi 20
5  CYCL DEF 215 WYSEP.KOL.NA GOT. ~
    Q200=+5    ;BEZPIECZNA WYSOKOSC ~
    Q201=-25   ;GLEBOKOSC ~
    Q206=+150  ;WARTOSC POSUWU WGL. ~
    Q202=+5    ;GLEBOKOSC DOSUWU ~
    Q207=+500  ;POSUW FREZOWANIA ~
    Q203=+25   ;WSPOLRZEDNE POWIERZ. ~
    Q204=+50   ;2-GA BEZPIECZNA WYS. ~
    Q216=+0    ;SRODEK W 1-SZEJ OSI ~
    Q217=+0    ;SRODEK W 2-SZEJ OSI ~
    Q222=+20   ;SREDNICA WST.OBR.WYB ~
    Q223=+20   ;SRED.WYBR.OBR.NA GOT
6  L  X+0  Y+0 FMAX M99 M3
7  L  Z+200 R0 FMAX
8  TOOL CALL 20 Z S3000
9  ;FREZ DO GWINTU M20X1.5
10 CYCL DEF 267 FREZOW. GWINTU ZEWN. ~
    Q335=+20   ;SREDNICA NOMINALNA ~
    Q239=+1.5  ;SKOK ~
    Q201=-20   ;GLEBOKOSC GWINTU ~
    Q355=+1    ;ILOSC KROKOW DO WYK. ~
    Q253=+750  ;PREDK. POS. ZAGLEB. ~
    Q351=+1    ;RODZAJ FREZOWANIA ~
    Q200=+10   ;BEZPIECZNA WYSOKOSC ~
    Q358=+0    ;GLEB. STRONA CZOLOWA ~
    Q359=+0    ;PRZES. NA STR. CZOL. ~
    Q203=+25   ;WSPOLRZEDNE POWIERZ. ~
    Q204=+50   ;2-GA BEZPIECZNA WYS. ~
    Q254=+200  ;PREDK. POS. POGLEB. ~
    Q207=+500  ;POSUW FREZOWANIA
11 L  X+0  Y+0 F4000 M99 M3
12 L  Z+200 R0 FMAX M9
13 M30
14 END PGM gwint MM

Mi wyszło coś takiego. Gwint widać skrobie

Post napisał: **WZÓR** » 10 wrz 2011, 14:15

martinprz pisze:Witam,
Czy moglibyście sprawdzić i poprawić mi cykle do frezowania czopa okrągłego 215 i do frezowania gwintu zewnętrznego...

Swoją pomoc podpieram Cam-em .... i myślę , że nic się nie stanie jak pomogę Tobie w ten sposób rozwiązać problem.
Gwintowanie (jak widać , na symulacji wyszło) , ale wygenerowany program wygląda mi jakoś podejrzanie .
Sprawdź programy u siebie i daj znać , czy zrobiłem to dobrze.
Program na frezowanie czopa post wyżej.

Obrazek

P.S.
program na gwintowanie w załączniku (ma 10 przejść zgrubnych - dlatego z lekka jest obszerny).

MECO · Post napisał: **MECO** » 10 wrz 2011, 14:35

Zarysu gwintu na grafice nie zobaczysz,jeżeli chcesz się przekonać czy frezuje czy nie to puść tylko frezowanie gwintu. A te rogi to daj większe narzędzie albo to co napisał WZÓR.

Post napisał: **WZÓR** » 10 wrz 2011, 23:40

MECO pisze:... A te rogi to daj większe narzędzie...

Witam
Większe narzędzie nic nie da , gdyż frez programujesz do ostrza narzędzia , które ściśle przylega do zewnętrznego jak i wewnętrznego konturu wybrania.
W tym przypadku jego średnica nie może być większa niż ø12.0 ... patrz rysunek.

Wejście freza

Obrazek

i jego wyjście po cyklu frezowania wybrania / czopa okrągłego.

Obrazek

Jak już wcześniej wspomniałem frezowanie wybrania / czopa okrągłego ograniczają zewnętrzne jak i wewnętrzne kontury wybrania , co powoduje , że frez zagłębia się w pełnym materiale.
Przy takim sposobie obróbki zaleca się poprzedzić operację frezowania wybrania / czopa okrągłego wstępnym wierceniem w miejscu zagłębiania się freza , o którym nikt (jak widać ) do tej pory nie wspomniał.

MECO - wcale nie mówię ,że nie masz racji ....

Tę symulację wykonałem w programie CAD/CAM wykorzystując inną metodę obróbki , gdzie wstępne wiercenie otworu jest zbędne .... średnica freza wynosi ø20.0

Wejście freza (poza granicą zewnętrzną konturu wybrania)

Obrazek

i jego wyjście po operacji frezowania.

Obrazek

kolor czerwony - G00
kolor zielony - G01
kolor biały - kontury wybrania

Pozdr
Mariusz.

MECO · Post napisał: **MECO** » 11 wrz 2011, 00:30

dlaczego nic nie da. Jeżeli jest jakaś kostka o wym. 44*52 a na niej czop fi 20 to dlaczego nie można dać większego narzędzia. Innym narzędziem frezuje czop a innym narzędziem frezuje gwint.Niema obawy że gdzieś "przychaczy".

Pozdro.

Problem z cyklami 215 i 267