iTNC 530 problem podczas symulacji

silver1990r · Post napisał: **silver1990r** » 28 mar 2012, 12:47

Jeśli chodzi o CNC to jestem początkujący i już coś tam skumałem jeśli chodzi o pisanie programu w itnc 530 heidenhain. Problem polega na tym że jak chce zapuścić symulacje to wyskakują błędy. Jeżeli nacisnę START to do góry pisze aktualny blok wybrany, a jak nacisnę START+RESET to pisze że narzędzie zblokowane. Ale także w niektórych programach co napisałem symulacja się rozpoczyna ale się zatrzymuje na pierwszym wierszu ewentualnie zrobi jakaś dziurę i to wszystko. I teraz pytanie co lub gdzie popełniłem błąd podczas pisania programu że wyskakują takie błędy

ciekavy · Post napisał: **ciekavy** » 28 mar 2012, 14:51

Brak zdefiniowanych narzędzi?
Źle zdefiniowana grafika?
Zła konstrukcja programu?
Możliwości jest wiele. Pokaż przykładowy program który nie działa.

silver1990r · Post napisał: **silver1990r** » 28 mar 2012, 16:20

oczywiscie moge pokazać jeden z programów tylko nie wiem jak skopiować to. Słyszałem że najplepiej jest konwertować przez TNCremo ale nie wiem jak je powiązać żeby to zrobić.
Narzędzia mam opisane jeśli chodzi o pormienie i długości.

ciekavy · Post napisał: **ciekavy** » 28 mar 2012, 17:05

Jeśli program jest krótki to daj screena. Jeśli dłuższy to instrukcja kopiowania jest gdzieś na forum.

silver1990r · Post napisał: **silver1990r** » 28 mar 2012, 17:25

na forum jak narazie to tylko znalazłem coś z kablami jeśli chodzi o przesyłanie a tak to jeszcze o tym że trzeba wejść w MOD wpisać NET123 i tyle tylko że po wpisaniu tego nic się nie dzieje a jak wpisze samo 123 to wyskakuje parę tych MP ale co trzeba zrobić to nie wiem.
no na screena cały program się nie zmieści niestety

ciekavy · Post napisał: **ciekavy** » 28 mar 2012, 17:33

Programy znajdują się w ścieżce \iTNC530\tnc w folderze z zainstalowanym symulatorem. Wrzuć program na jakiś hosting a ja go wrzucę u siebie na symulator. Później napisze jak kopiować programy.

[ Dodano: 2012-03-28, 17:53 ]

Odpalamy symulator

Wchodzimy w edycje

PGM MGT do listy programów

Najeżdżamy na program który chcemy skopiować

Wciskamy klawisz F10 na klawiaturze komputera do pojawienia się OKNO na dole symulatora

Wciskamy OKNO (pojawiają się dwie kolumny)

Przechodzimy kursorem na prawą stronę okna

Naciskamy PATH (jeśli nie ma to F9/F10 aż się pojawi)

Wybieramy miejsce zapisu programu

Wciskamy klawisz F9 na klawiaturze komputera aż pojawi się na dole KOPIUJ

Kursorem wracamy na lewą stronę i najeżdżamy na program który chcemy skopiowac

Wciskamy KOPIUJ

Jeśli potrzeba zmieniamy nazwę pliku końcowego (rozszerzenie najlepiej zostawić) i OK

Klikamy OKNO i kopiowanie zakończone.
Analogicznie wgrywamy program na symulator/maszynę.

silver1990r · Post napisał: **silver1990r** » 28 mar 2012, 21:58

podaj e mail tak będzie mi łatwiej

no a to od myślników to jutro zobaczę

[ Dodano: 2012-03-29, 16:16 ]
No np taki program mam i cos jest zle ale nie wiem co ze symulacja nie idzie
0 BEGIN PGM PROBA MM
1 BLK FORM 0.1 Z X+0 Y+0 Z+0
2 BLK FORM 0.2 X+320 Y+230 Z+50
3 CALL LBL 1
4 TOOL CALL 13 Z S2000 F120 ;frez_D12
5 CYCL DEF 14.0 GEOMETRIA KONTURU
6 CYCL DEF 14.1 PODPR.KONTURU1
7 CYCL DEF 20 DANE KONTURU ~
Q1=-50 ;GLEBOKOSC FREZOWANIA ~
Q2=+1 ;ZACHODZENIE TOROW ~
Q3=+0 ;NADDATEK NA STRONE ~
Q4=+0 ;NADDATEK NA DNIE ~
Q5=+0 ;WSPOLRZEDNE POWIERZ. ~
Q6=+200 ;BEZPIECZNA WYSOKOSC ~
Q7=+200 ;BEZPIECZNA WYSOKOSC ~
Q8=+0 ;PROMIEN ZAOKRAGLENIA ~
Q9=-1 ;KIERUNEK OBROTU
8 CALL LBL 1
9 STOP M30
10 LBL 1
11 * - lbl 1 - kontur
12 L X+0 Y+0 F200 M13
13 L Y+130 R0 F220
14 L IX+50 F200
15 L IY+90 F200
16 L IX+100 F200
17 L IY-50 F200
18 L IX+160 F200
19 L IY-100 F200
20 L IX-60 F200
21 L IY-60 F200
22 L IX-250 F200
23 LBL 0
24 END PGM PROBA MM

ciekavy · Post napisał: **ciekavy** » 31 mar 2012, 21:29

Po małych poprawach program działa. Powiedz czy miał robić to co wyszło na mojej symulacji. Zmieniłem cykl 20 na 25 oraz definicję grafiki
0 BEGIN PGM proba MM
1 BLK FORM 0.1 Z X+0 Y+0 Z-50
2 BLK FORM 0.2 X+320 Y+230 Z+0
3 TOOL CALL 13 Z S2000 F120 ;frez_D12
4 CYCL DEF 14.0 GEOMETRIA KONTURU
5 CYCL DEF 14.1 PODPR.KONTURU1
6 CYCL DEF 25 KONTUR OTWARTY ~
Q1=-50 ;GLEBOKOSC FREZOWANIA ~
Q3=+0 ;NADDATEK NA STRONE ~
Q5=+0 ;WSPOLRZEDNE POWIERZ. ~
Q7=+50 ;BEZPIECZNA WYSOKOSC ~
Q10=-1 ;GLEBOKOSC DOSUWU ~
Q11=+150 ;WARTOSC POSUWU WGL. ~
Q12=+500 ;POSUW PRZY ROZWIERC. ~
Q15=+1 ;RODZAJ FREZOWANIA
7 CYCL CALL M3
8 STOP M30
9 LBL 1
10 * - lbl 1 - kontur
11 L X+0 Y+0 F200 M13
12 L Y+130 R0 F220
13 L IX+50 F200
14 L IY+90 F200
15 L IX+100 F200
16 L IY-50 F200
17 L IX+160 F200
18 L IY-100 F200
19 L IX-60 F200
20 L IY-60 F200
21 L IX-250 F200
22 LBL 0
23 END PGM proba MM

silver1990r · Post napisał: **silver1990r** » 01 kwie 2012, 23:40

tak poprostu ma zrobić kontur narazie zaczynam sie tego uczyć a udało mi sie to zrobić troche w inny sposób jutro wrczuce a mam pytanie czy mogłbyś np dopisac do tego jeszcze jakieś podprogramy ?? bo probuje w domu do tego dodac jeszce jeden podprogram np. wiercenie albo cos innego?? bo ja zrobilem pod program do wiercenia lecz jak pisze cykl to poprostu symulacja tego nie robi

ciekavy · Post napisał: **ciekavy** » 02 kwie 2012, 13:23

Program kolegi z forum w kttórym mu pomagałem.

0 BEGIN PGM kontor MM
1 BLK FORM 0.1 Z X-26 Y-22 Z-20
2 BLK FORM 0.2 X+26 Y+22 Z+0
3 TOOL CALL 12 Z S2000
4 ;frez palcowy fi12
5 L Z+200 R0 FMAX
6 L X-40 Y-15 FMAX
7 CYCL DEF 14.0 GEOMETRIA KONTURU
8 CYCL DEF 14.1 PODPR.KONTURU1
9 CYCL DEF 25 KONTUR OTWARTY ~
Q1=-11 ;GLEBOKOSC FREZOWANIA ~
Q3=+0.5 ;NADDATEK NA STRONE ~
Q5=+0 ;WSPOLRZEDNE POWIERZ. ~
Q7=+50 ;BEZPIECZNA WYSOKOSC ~
Q10=-5 ;GLEBOKOSC DOSUWU ~
Q11=+150 ;WARTOSC POSUWU WGL. ~
Q12=+500 ;POSUW PRZY ROZWIERC. ~
Q15=+1 ;RODZAJ FREZOWANIA
10 CYCL CALL M3 M8
11 L Z+200 R0 FMAX M9
12 TOOL CALL 13 Z S3000
13 ;frez palcowy do rowkow fi8
14 L Z+200 R0 FMAX
15 CYCL DEF 251 KIESZEN PROSTOKATNA ~
Q215=+0 ;RODZAJ OBROBKI ~
Q218=+20 ;DLUG. 1-SZEJ STRONY ~
Q219=+20 ;DLUG. 2-GIEJ STRONY ~
Q220=+5 ;PROMIEN NAROZA ~
Q368=+0.2 ;NADDATEK NA STRONE ~
Q224=+0 ;KAT OBROTU ~
Q367=+0 ;POLOZENIE KIESZENI ~
Q207=+500 ;POSUW FREZOWANIA ~
Q351=+1 ;RODZAJ FREZOWANIA ~
Q201=-9 ;GLEBOKOSC ~
Q202=+3 ;GLEBOKOSC DOSUWU ~
Q369=+0.1 ;NADDATEK NA DNIE ~
Q206=+150 ;WARTOSC POSUWU WGL. ~
Q338=+5 ;POSUW - OBR.WYKONCZ. ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS. ~
Q370=+1 ;ZACHODZENIE TOROW ~
Q366=+1 ;ZAGLEBIANIE ~
Q385=+500 ;POSUW OBR.WYKAN.
16 CYCL CALL POS X+0 Y+0 Z+0 FMAX M3 M8
17 L Z+200 R0 FMAX M9 M6
18 TOOL CALL 14 Z S700 F300
19 ;wiertlo fi4.8
20 L Z+200 R0 FMAX M3 M8
21 CYCL DEF 200 WIERCENIE ~
Q200=+50 ;BEZPIECZNA WYSOKOSC ~
Q201=-12.4421 ;GLEBOKOSC ~
Q206=+150 ;WARTOSC POSUWU WGL. ~
Q202=+4 ;GLEBOKOSC DOSUWU ~
Q210=+0 ;PRZER. CZAS.NA GORZE ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS. ~
Q211=+0.1 ;PRZERWA CZAS. DNIE
22 CYCL DEF 220 SZABLON KOLOWY ~
Q216=+0 ;SRODEK W 1-SZEJ OSI ~
Q217=+0 ;SRODEK W 2-SZEJ OSI ~
Q244=+32 ;SREDNICA PODZ.OKREGU ~
Q245=+60 ;KAT POCZATKOWY ~
Q246=+360 ;KAT KONCOWY ~
Q247=+60 ;KATOWY PRZYROST-KROK ~
Q241=+6 ;LICZBA POWTORZEN ~
Q200=+10 ;BEZPIECZNA WYSOKOSC ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS. ~
Q301=+1 ;ODJAZD BEZPIECZNY ~
Q365=+1 ;RODZAJ PRZEMIESZCZ.
23 L Z+200 R0 FMAX M9 M6
24 M2
25 LBL 1
26 L X-26 Y+0 RL
27 CR X-23 Y+11 R+20.6 DR-
28 CR X-15 Y+19 R+8 DR+
29 CR X+15 Y+19 R+70.48 DR+
30 CR X+23 Y+11 R+8 DR+
31 CR X+23 Y-11 R+20.6 DR-
32 CR X+15 Y-19 R+8 DR+
33 CR X-15 Y-19 R+70.48 DR+
34 CR X-23 Y-11 R+8 DR+
35 CR X-26 Y+0 R+20.6 DR-
36 L X-40 Y+0
37 LBL 0
38 END PGM kontor MM

iTNC 530 problem podczas symulacji