'===============================================================================================================

'Macro najazdu na wskaznik lasera V1
'2013-04-09 00:32

'===============================================================================================================
Const NewPoz_X = 30 'różnica odległosci w osi X miedzy frezem a laserem, ważny jest znak wartości
Const NewPoz_Y = 30 'różnica odległosci w osi Y miedzy frezem a laserem, ważny jest znak wartości
Const FeedMove = 500 'prędkość przejazdów
'===============================================================================================================
Dim ZDROsaveCord 'Pozycja osi Z przed wywołaniem PROBE
Dim Inc 'Gdy 1 ruch inkrementalny , 0 absolutny
Dim MachCoor 'Gdy 1 kordynaty programowe
Dim FeedCurrent 'Zapis prędkosci
'===============================================================================================================
'Główny program
'===============================================================================================================

Sub Main

'--------------------------------------------------------------------

If GetOEMLed(806) Or GetOEMLed(807) Or GetOEMLed(809) Then
StopRewindSleep
Message"ERROR: Maszyna nie zbazowana !!!"
End
ElseIf GetOEMLed(11) Then
StopRewindSleep
Message"ERROR: wrzeciono pracuje"
End
End If

'--------------------------------------------------------------------
SaveMachCoor
SaveIncAbs
SaveFeedCurrent
ZDROsaveCord = GetOEMDro(802)
'--------------------------------------------------------------------

Code"G90"
WaitForMove
Code "G53 G0 Z0"
WaitForMove

Code"G91"
WaitForMove
Code"G1 X" & NewPoz_X & " Y" & NewPoz_Y & " F" & FeedMove
WaitForMove

Code"G90"
WaitForMove
Code"G1 Z" & ZDROsaveCord & " F" & FeedMove
WaitForMove

SetOEMDro(800, 0)
SetOEMDro(801, 0)

Sleep(1000)

'--------------------------------------------------------------------
RestoreFeedCurrent
RestoreIncAbs
RestoreMachCoor
'--------------------------------------------------------------------

End Sub


'===============================================================================================================
'Funkcje
'===============================================================================================================
Sub SaveMachCoor ()
If GetOEMLed(16) Then
DoOEMButton(256)
MachCoor = 1
Else
MachCoor = 0
End If
End Sub
'-------------------------------------------
Sub RestoreMachCoor ()
If MachCoor = 1 Then
If Not GetOEMLed(16) Then
DoOEMButton(256)
End If
Else
If GetOEMLed(16) Then
DoOEMButton(256)
End If
End If
End Sub
'-------------------------------------------
'-------------------------------------------
Sub SaveIncAbs ()
If GetOEMLed(49) Then
Inc = 1
Else
Inc = 0
End If
End Sub
'-------------------------------------------
Sub RestoreIncAbs ()
If Inc = 1 Then
Code"G91"
WaitForMove
Else
Code"G90"
WaitForMove
End If
End Sub
'-------------------------------------------
'-------------------------------------------
Sub SaveFeedCurrent ()
FeedCurrent = GetOEMDRO(818)
End Sub
'-------------------------------------------
Sub RestoreFeedCurrent ()
Code "F" &FeedCurrent
WaitForMove

End Sub
'-------------------------------------------
'-------------------------------------------
Sub StopRewindSleep ()
DoOEMButton(1003)
DoOEMButton(1002)
Sleep(150)
End Sub
'-------------------------------------------
'-------------------------------------------
Sub WaitForMove ()
While IsMoving()
Sleep(15)
Wend
End Sub
'===============================================================================================================



Macro zapamiętuje prędkość posuwu , czy jest w koordynatach maszynowych , czy jest w g90 czy g91 i na koniec przywraca poprzedni stan

do przejazdu podnoś się do 0 maszynowego i opada do poprzedniej wysokości w osi Z , kontroluje zabazowanie osi.

Miłej zabawy w testowaniu Poniżej plik do pobrania

mam prawie już całe zrobione macro


w sobotę posprawdzam i udostępnię tu na forum bo obecnie nie mam czasu

kolanoreki

jak laser jest zamontowany obok i świeci pionowo to niema problemu

ok pomogę ci , niema problemu.

Przypomnij mi się na pw za 2, 3 dni

[ Dodano: 2013-04-08, 01:53 ]
a tak od menie to niema znaczenia czy zamontujesz 2 czy 10 laserów jeśli dobrze ustawisz to i jeden wystarczy