Cycl14 to "przeżytek" . Polecam CONTOUR DEF (SPEC FCT->KONTUR/PUNKT OBR.->).
Mozna okresic w nim dodatkowo glebokosc Z-5 Wysp.
Wkleilem maly przyklad - pomijam aspekty technologiczne obr. Ap i posuw.
Nr narzedzi to ich srednice.
plik cypelekDEF.h GLOWNY
0 BEGIN PGM cypelekDEF MM
1 BLK FORM 0.1 Z X-30 Y-30 Z-20
2 BLK FORM 0.2 X+30 Y+30 Z+0
3 ;
4 TOOL CALL 6 Z S1000
5 CONTOUR DEF ~
P1 = "cypelekWYB.h" ~
I2 = "cypelekWYS.h" ~
DEPTH5
6 CYCL DEF 20 DANE KONTURU ~
Q1=-10 ;GLEBOKOSC FREZOWANIA ~
Q2=+1 ;ZACHODZENIE TOROW ~
Q3=+0 ;NADDATEK NA STRONE ~
Q4=+0 ;NADDATEK NA DNIE ~
Q5=+0 ;WSPOLRZEDNE POWIERZ. ~
Q6=+2 ;BEZPIECZNA WYSOKOSC ~
Q7=+20 ;BEZPIECZNA WYSOKOSC ~
Q8=+5 ;PROMIEN ZAOKRAGLENIA ~
Q9=+1 ;KIERUNEK OBROTU
7 CYCL DEF 21 NAWIERCANIE ~
Q10=-2.5 ;GLEBOKOSC DOSUWU ~
Q11=+150 ;WARTOSC POSUWU WGL. ~
Q13=+4 ;ZDZIERAK
8 L Z+150 R0 FMAX M3
9 CYCL CALL M8
10 ;
11 TOOL CALL 4 Z S10000 F666
12 CYCL DEF 22 FREZ.ZGR.WYBRANIA ~
Q10=-10 ;GLEBOKOSC DOSUWU ~
Q11= AUTO ;WARTOSC POSUWU WGL. ~
Q12= AUTO ;POSUW PRZY ROZWIERC. ~
Q18=+0 ;NARZ.DO OBR.ZGRUB. ~
Q19=+0 ;POSUW PRZY R. WAHAD. ~
Q208= MAX ;POSUW RUCHU POWROTN. ~
Q401=+100 ;WSPOLCZYNNIK POSUWU ~
Q404=+0 ;STRAT.PRZEC.WYKONCZ.
13 L Z+150 R0 FMAX M3
14 CYCL CALL M8
15 ;
16 TOOL CALL 3 Z S2222
17 CYCL DEF 20 DANE KONTURU ~
Q1=-10 ;GLEBOKOSC FREZOWANIA ~
Q2=+1 ;ZACHODZENIE TOROW ~
Q3=+0 ;NADDATEK NA STRONE ~
Q4=+0 ;NADDATEK NA DNIE ~
Q5=+0 ;WSPOLRZEDNE POWIERZ. ~
Q6=+2 ;BEZPIECZNA WYSOKOSC ~
Q7=+20 ;BEZPIECZNA WYSOKOSC ~
Q8=+0 ;PROMIEN ZAOKRAGLENIA ~
Q9=+1 ;KIERUNEK OBROTU
18 CYCL DEF 22 FREZ.ZGR.WYBRANIA ~
Q10=-2.5 ;GLEBOKOSC DOSUWU ~
Q11= AUTO ;WARTOSC POSUWU WGL. ~
Q12= AUTO ;POSUW PRZY ROZWIERC. ~
Q18=+4 ;NARZ.DO OBR.ZGRUB. ~
Q19=+0 ;POSUW PRZY R. WAHAD. ~
Q208= MAX ;POSUW RUCHU POWROTN. ~
Q401=+100 ;WSPOLCZYNNIK POSUWU ~
Q404=+1 ;STRAT.PRZEC.WYKONCZ.
19 L Z+150 R0 FMAX M3
20 CYCL CALL M8
21 M30
22 END PGM cypelekDEF MM
i pliki w tym samym katalogu
cypelekWYB.h
0 BEGIN PGM cypelekWYB MM
1 L X+25 Y+0 RL
2 L Y+25
3 L X-25
4 L Y-25
5 L X+25
6 L Y+0
7 END PGM cypelekWYB MM
oraz cypelekWYS.h
0 BEGIN PGM cypelekWYS MM
1 CC X-5 Y+0
2 LP PR+13 PA+0 R0
3 C DR-
4 END PGM cypelekWYS MM
W tym ostatnim to mozna nawet opuscic kompensacje promienia.
Nie ma w nich rownierz BLK FRM
