Strona 1 z 1
Jak to zrobić
: 20 gru 2017, 09:56
autor: Lzoor
Witam, poradźcie fachowcy jak wykonać. Mam w imadle zamocowany materiał 150x150mm, do wykonania mam jakiś kontur który już mam napisany , tylko że problem jest w tym że ten kontur ma zostać a reszta ma być odjęta, próbowałem resztki ręcznie wyfrezować ale efekt nie jest zadowalający. Możecie poradzić jak to wykonać? Może jakiś cykl na frezowanie resztek jest ale który bo ja nie długo na heidenhainie pracuję i dopiero ogarniam co i jak.
Re: Jak to zrobić
: 20 gru 2017, 14:58
autor: Steryd
Dodajesz kontur prostokąta po zewnętrznym zarysie z luzem do cyklu 14. Obrabia Ci wszystko pomiędzy.
Naucz się pisać.
Re: Jak to zrobić
: 20 gru 2017, 20:55
autor: Lzoor
Mógłbyś trochę jaśniej? czyli jak mam już jakiś kontur na środku opisany np. w LBL1 to w cyklu 14 podaje LBL1 i to wystarczy ?
Re: Jak to zrobić
: 20 gru 2017, 22:13
autor: MAREK POCHRON
Czesc. SL- cykle . Popatrz na moje wczesniejsze posty
Re: Jak to zrobić
: 20 gru 2017, 22:29
autor: Steryd
Podajesz tyle lbli ile Ci potrzeba
Re: Jak to zrobić
: 26 gru 2017, 16:38
autor: rafa30
witam podaje przyklad programu ktory ja wykorzystuje do takich wybran zobacz sobie na symulatorze
0 BEGIN PGM SZESCIOKAT-CYKL MM
1 BLK FORM 0.1 Z X-120 Y-120 Z-100
2 BLK FORM 0.2 X+120 Y+120 Z+0
3 TOOL CALL 4 Z S1300 F5000 DL+0 DR+0
4 L Z+100 R0 FMAX M3
5 L X+0 Y+80 R0 FMAX
6 CYCL DEF 14.0 GEOMETRIA KONTURU
7 CYCL DEF 14.1 PODPR.KONTURU3 /1
8 CYCL DEF 20 DANE KONTURU ~
Q1=-70 ;GLEBOKOSC FREZOWANIA ~
Q2=+0 ;ZACHODZENIE TOROW ~
Q3=+0 ;NADDATEK NA STRONE ~
Q4=+0 ;NADDATEK NA DNIE ~
Q5=+0 ;WSPOLRZEDNE POWIERZ. ~
Q6=+2 ;BEZPIECZNA WYSOKOSC ~
Q7=+2 ;BEZPIECZNA WYSOKOSC ~
Q8=+0 ;PROMIEN ZAOKRAGLENIA ~
Q9=-1 ;KIERUNEK OBROTU
9 CYCL DEF 22 FREZ.ZGR.WYBRANIA ~
Q10=-2 ;GLEBOKOSC DOSUWU ~
Q11=+200 ;WARTOSC POSUWU WGL. ~
Q12=+1000 ;POSUW PRZY ROZWIERC. ~
Q18=+0 ;NR NARZ.DO ZGRUB.OBR ~
Q19=+0 ;POSUW PRZY R. WAHAD. ~
Q208=+99999 ;POSUW RUCHU POWROTN. ~
Q401=+100 ;FEED RATE REDUCTION ~
Q404=+0 ;FINE ROUGH STRATEGY
10 CYCL CALL M3
11 L M2
12 LBL 1
13 CYCL DEF 10.0 OBROT
14 CYCL DEF 10.1 ROT+0
15 FN 0: Q2 =+0
16 FN 0: Q11 =+6
17 FN 0: Q4 =+115.47
18 FN 4: Q12 =+360 DIV +Q11
19 FN 0: Q2 =+Q12
20 LBL 2
21 CC X+0 Y+0
22 LP PR+Q4 PA+Q12 RR F100
23 FN 1: Q12 =+Q12 + +Q2
24 FN 1: Q11 =+Q11 + -1
25 FN 10: IF +Q11 NE -2 GOTO LBL 2
26 LBL 0
27 LBL 3
28 L Y+135 RL
29 L X-135
30 L Y-135
31 L X+135
32 L Y+135
33 L X+0
34 LBL 0
35 END PGM SZESCIOKAT-CYKL MM