gwintowanie .....

[eRMD]

Witam, mam taki problem:

wiercenie, nawiercanie z wykorzystaniem tabeli punktów zerowych idzie bez problemu a co z gwintowaniem zrobic jak nie chce przeskoczyc do drugiego otworu ???? Komunikat "Potrzebne M3/M4 lub M19/M20" Dodałem i tez nie idzie, czego lub jakiego "M" moze jeszcze brakowac ????

Staram sie pisac od niedawna wiec jeszcze jestem naprawde w tym zielony ale takie prymitywne obejscie udało mi sie znaleść.


109 TOOL CALL 6 Z S1300
110 L Z+50 R0 FMAX M3
111 SEL PATTERN "251002105"
112 CYCL DEF 200 WIERCENIE ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q201=-11 ;GLEBOKOSC ~
Q206=+180 ;WARTOSC POSUWU WGL. ~
Q202=+11 ;GLEBOKOSC DOSUWU ~
Q210=+0 ;PRZER. CZAS.NA GORZE ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS. ~
Q211=+0 ;PRZERWA CZAS. DNIE
113 CYCL CALL PAT F10000
114 L Z+200 R0 FMAX
115 TOOL CALL 7 Z S100
116 L Z+50 R0 FMAX M3
117 L X-248 Y+44 R0 FMAX M3
118 LBL 1
119 CYCL DEF 207 GWINTOWANIE GS-NOWE ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q201=-18 ;GLEBOKOSC GWINTU ~
Q239=+1.25 ;SKOK ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS.
120 CYCL CALL M3
121 LBL 0
122 L X-248 Y-44 R0 FMAX M3
123 CALL LBL 1
124 L X+173.5 Y+44 R0 FMAX M3
125 CALL LBL 1
126 L X+173.5 Y-44 R0 FMAX M3
127 CALL LBL 1
128 L X+272.5 Y-44 R0 FMAX M3
129 CALL LBL 1
130 L X+272.5 Y+44 R0 FMAX M3
131 CALL LBL 1
132 L Z+200 R0 FMAX
133 L Y+220 R0 FMAX
134 TOOL CALL 1
135 END PGM 251002105 MM

[Wally77]

Po pierwsze brakuje Ci, po wywołaniu narzedzia funkcji M6, powinna być w nastepnej lini po tool call.
A po drugie, dla mnie troche bez sensu jest Twoj label 1, możesz zamiast tego, po każdym najeździe narzędzia na daną pozycje użyć funkcji M99, wg mnie łatwiej i czytelniej,
np

115 TOOL CALL 7 Z S100
116 M6
119 CYCL DEF 207 GWINTOWANIE GS-NOWE ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q201=-18 ;GLEBOKOSC GWINTU ~
Q239=+1.25 ;SKOK ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS.
117 L X-248 Y+44 R0 FMAX M13
116 L Z+2 R0 FMAX M99
122 L X-248 Y-44 R0 FMAX M99
124 L X+173.5 Y+44 R0 FMAX M99
126 L X+173.5 Y-44 R0 FMAX M99
128 L X+272.5 Y-44 R0 FMAX M99
.
.
.
.
itd...


Nie zwracaj proszę uwagi na numeracje wierszy, nie chciało mi sie zmieniac.

Pozdrawiam i powodzenia.

[eRMD]

Witam dzieki wielkie, co do M6 to pisałem na TNCi530 i bez M6 tez idzie. A do M99 dzis potestuje i sprawdzę. Pozdrawiam

[M@ciej]

witam !
ja bym zrobił tak

tool call 6 Z S1300
cycl def 200
call lbl 1
tool call 7 Z S 100
cycl def 207
call lbl1
tool call 0 Z
M30
lbl set 1
M13
L X... Y .... R0 F max M99
L współżędne otworów
L
L
L
Lbl set 0

do większej ilości otwoów można zastosować funkcję M89 a w ostatnim otworze dać M99
ale w tedy trzeba podać przy tool call F z jaki ma się przemieszczać narzędzie pomiędzy otworami ( i ni e trzeba nadużywać przucisku enter)

[eRMD]

tak wszystko ładnie i pieknie, naprawdę to działa ale jeśli mam 200 otworów to jak zrobić by wykorzystać tabele punktów tak jak jest w moim przykładzie z wierceniem (powiedzmy ze niesymetrycznie rozmieszczone i wykorzystanie cyklu 220 i 221 nie wchodzą w grę)

[kaleena]

Nie może kolega zrobić LBL-a ze współrzędnymi otworów i po prostu wywoływać go - tak chyba najprościej i najszybciej.

[M@ciej]

Jeżeli nie ma żadnej reguły według której są rozstawione otwory, np wykorzystują funkcje I równo po osiach , lub używać tylko jadnej wspolnej wsp.
np

x 3,25 y 5,6 R0 F max M 89
x 4, 48
x 7,77
x9,02
x 3,48 y 8,44
x
x
x

moim zdaniem trzeba wklepać wszystko.

[rollaz]

proponuje ci kolego prosty i bardzo przejrzysty programik


0 BEGIN PGM M10 MM
1 ; ****************************
2 * - hm-spiri-8.5
3 TOOL CALL 23 Z S3200
4 TOOL DEF 3
5 ; ****************************
6 L X+0 Y+0 Z+100 R0 FMAX
7 L Z+50 R0 FMAX M3 M7
8 CYCL DEF 203 UNIWERSL WIERC. ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q201=-25 ;GLEBOKOSC ~
Q206=+400 ;WARTOSC POSUWU WGL. ~
Q202=+1 ;GLEBOKOSC DOSUWU ~
Q210=+0 ;PRZER. CZAS.NA GORZE ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS. ~
Q212=+0 ;WART. ZMNIEJ. DOSUWU ~
Q213=+100 ;LICZBA LAMAN WIORA ~
Q205=+0 ;MIN. GLEBOK. DOSUWU ~
Q211=+0 ;PRZERWA CZAS. DNIE ~
Q208=+30000 ;POSUW RUCHU POWROTN. ~
Q256=+0,2 ;WYCOF.DLA ZLAM.WIORA
9 CALL LBL 1
10 L Z+200 R0 FMAX M5
11 ; ****************************
12 * - faza-45
13 TOOL CALL 3 Z S8000
14 TOOL DEF 22
15 ; ****************************
16 L X+0 Y+0 Z+100 R0 FMAX
17 L Z+50 R0 FMAX M3 M18
18 CYCL DEF 208 FREZOWANIE OTOWROW ~
Q200=+0,5 ;BEZPIECZNA WYSOKOSC ~
Q201=-3 ;GLEBOKOSC ~
Q206=+2000 ;WARTOSC POSUWU WGL. ~
Q334=+3 ;GLEBOKOSC DOSUWU ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS. ~
Q335=+10 ;SREDNICA NOMINALNA ~
Q342=+9 ;ZADANA SREDNICA
19 CALL LBL 1
20 L Z+200 R0 FMAX M5
21 ; ****************************
22 * - gewinde-M10
23 TOOL CALL 22 Z S200
24 STOP
25 ; ****************************
26 L X+0 Y+0 Z+100 R0 FMAX
27 L Z+50 R0 FMAX M3
28 CYCL DEF 207 GWINTOWANIE GS-NOWE ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q201=-24 ;GLEBOKOSC GWINTU ~
Q239=+1,5 ;SKOK ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS.
29 CALL LBL 1
30 L Z+100 R0 FMAX M5
31 L X+0 Y+0 Z+0 R0 FMAX M92
32 STOP M30
33 * - ###################
34 LBL 1
35 * - LBL1 otwory M10
36 L X+19 Y+35 R0 FMAX M99
37 L X-19 Y-35 R0 FMAX M99
38 LBL 0
39 END PGM M10 MM

[eRMD]

dzieki za pomoc, wolnymi chwilami bedę praktykowac.