Mylisz pojęcia. Podprogram to program w osobnym pliku który jest wywoływany za pomocą programu głównego. W Twoim przypadku wywołujesz cykle (wiercenie, gwintowanie itd)

silver1990r pisze:Jak bym chciał dodać kolejny podprogram to żeby go wywołać to najpierw podaje cycl def a później cycl lbl itd??

Przykład masz w programie wyżej, ale przeważnie tak chyba że jest to osobny program wtedy PGM CALL

0 BEGIN PGM p MM
1 BLK FORM 0.1 Z X+0 Y+0 Z-50
2 BLK FORM 0.2 X+320 Y+230 Z+0
3 TOOL CALL 6 Z S2000 ;frez_D12
4 L Z+50 R0 F5000 M3
5 L X+0 Y+0
6 L Z+1 F2000
7 CYCL DEF 14.0 GEOMETRIA KONTURU
8 CYCL DEF 14.1 PODPR.KONTURU1
9 CYCL DEF 20 DANE KONTURU ~
Q1=-50 ;GLEBOKOSC FREZOWANIA ~
Q2=+1 ;ZACHODZENIE TOROW ~
Q3=+0 ;NADDATEK NA STRONE ~
Q4=+0 ;NADDATEK NA DNIE ~
Q5=+0 ;WSPOLRZEDNE POWIERZ. ~
Q6=+1 ;BEZPIECZNA WYSOKOSC ~
Q7=+50 ;BEZPIECZNA WYSOKOSC ~
Q8=+0 ;PROMIEN ZAOKRAGLENIA ~
Q9=+1 ;KIERUNEK OBROTU
10 CYCL DEF 16.0 FREZOWANIE KONTURU
11 CYCL DEF 16.1 ODSTEP0.2 GLEBOK-50
12 CYCL DEF 16.2 DOSUW0.25 F1000 DR+ F2000
13 CYCL CALL
14 CYCL DEF 200 WIERCENIE ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q201=-50 ;GLEBOKOSC ~
Q206=+150 ;WARTOSC POSUWU WGL. ~
Q202=+1 ;GLEBOKOSC DOSUWU ~
Q210=+0 ;PRZER. CZAS.NA GORZE ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS. ~
Q211=+0 ;PRZERWA CZAS. DNIE
15 CALL LBL 2
16 L Z+150 R0 FMAX M2
17 LBL 1
18 * - lbl 1 - kontur
19 L X+0 Y+0
20 L IY+130 RL
21 CHF 15 F AUTO
22 L IX+50
23 CHF 15
24 L IY+90
25 L IX+100
26 CHF 15
27 L IY-50
28 CHF 15
29 L IX+160
30 CHF 15
31 L IY-110
32 CHF 15
33 L IX-60
34 CHF 15
35 L IY-60
36 L IX+0 IY+0
37 LBL 0
38 LBL 2
39 * - lbl 2 -wiercenie
40 M3 M8
41 L X+150 Y+150 FMAX M99
42 LBL 0
43 END PGM p MM

Program poprawiony. CC wyznacza środek okręgu i nie zadziała sam w sobie.
Polecam mała lekturę która dużo Ci pomoże
http://www.zmt.mt.put.poznan.pl/CNC/364_816-83.pdf

Jakie podprogramy? Masz na myśli inny program napisany w oddzielnym programie?
Jeśli tak to wystarczy wcisnąć PGM CALL i podać nazwę programu jeśli jest w tym samym folderze. Jeśli nie jest to trzeba podać dokładną ścieżkę do programu.
Jeśli nie o to chodzi to dokładniej sprecyzuj pytanie, ewentualnie zamieść programy które mają być użyte.

Program kolegi z forum w kttórym mu pomagałem.

0 BEGIN PGM kontor MM
1 BLK FORM 0.1 Z X-26 Y-22 Z-20
2 BLK FORM 0.2 X+26 Y+22 Z+0
3 TOOL CALL 12 Z S2000
4 ;frez palcowy fi12
5 L Z+200 R0 FMAX
6 L X-40 Y-15 FMAX
7 CYCL DEF 14.0 GEOMETRIA KONTURU
8 CYCL DEF 14.1 PODPR.KONTURU1
9 CYCL DEF 25 KONTUR OTWARTY ~
Q1=-11 ;GLEBOKOSC FREZOWANIA ~
Q3=+0.5 ;NADDATEK NA STRONE ~
Q5=+0 ;WSPOLRZEDNE POWIERZ. ~
Q7=+50 ;BEZPIECZNA WYSOKOSC ~
Q10=-5 ;GLEBOKOSC DOSUWU ~
Q11=+150 ;WARTOSC POSUWU WGL. ~
Q12=+500 ;POSUW PRZY ROZWIERC. ~
Q15=+1 ;RODZAJ FREZOWANIA
10 CYCL CALL M3 M8
11 L Z+200 R0 FMAX M9
12 TOOL CALL 13 Z S3000
13 ;frez palcowy do rowkow fi8
14 L Z+200 R0 FMAX
15 CYCL DEF 251 KIESZEN PROSTOKATNA ~
Q215=+0 ;RODZAJ OBROBKI ~
Q218=+20 ;DLUG. 1-SZEJ STRONY ~
Q219=+20 ;DLUG. 2-GIEJ STRONY ~
Q220=+5 ;PROMIEN NAROZA ~
Q368=+0.2 ;NADDATEK NA STRONE ~
Q224=+0 ;KAT OBROTU ~
Q367=+0 ;POLOZENIE KIESZENI ~
Q207=+500 ;POSUW FREZOWANIA ~
Q351=+1 ;RODZAJ FREZOWANIA ~
Q201=-9 ;GLEBOKOSC ~
Q202=+3 ;GLEBOKOSC DOSUWU ~
Q369=+0.1 ;NADDATEK NA DNIE ~
Q206=+150 ;WARTOSC POSUWU WGL. ~
Q338=+5 ;POSUW - OBR.WYKONCZ. ~
Q200=+2 ;BEZPIECZNA WYSOKOSC ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS. ~
Q370=+1 ;ZACHODZENIE TOROW ~
Q366=+1 ;ZAGLEBIANIE ~
Q385=+500 ;POSUW OBR.WYKAN.
16 CYCL CALL POS X+0 Y+0 Z+0 FMAX M3 M8
17 L Z+200 R0 FMAX M9 M6
18 TOOL CALL 14 Z S700 F300
19 ;wiertlo fi4.8
20 L Z+200 R0 FMAX M3 M8
21 CYCL DEF 200 WIERCENIE ~
Q200=+50 ;BEZPIECZNA WYSOKOSC ~
Q201=-12.4421 ;GLEBOKOSC ~
Q206=+150 ;WARTOSC POSUWU WGL. ~
Q202=+4 ;GLEBOKOSC DOSUWU ~
Q210=+0 ;PRZER. CZAS.NA GORZE ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS. ~
Q211=+0.1 ;PRZERWA CZAS. DNIE
22 CYCL DEF 220 SZABLON KOLOWY ~
Q216=+0 ;SRODEK W 1-SZEJ OSI ~
Q217=+0 ;SRODEK W 2-SZEJ OSI ~
Q244=+32 ;SREDNICA PODZ.OKREGU ~
Q245=+60 ;KAT POCZATKOWY ~
Q246=+360 ;KAT KONCOWY ~
Q247=+60 ;KATOWY PRZYROST-KROK ~
Q241=+6 ;LICZBA POWTORZEN ~
Q200=+10 ;BEZPIECZNA WYSOKOSC ~
Q203=+0 ;WSPOLRZEDNE POWIERZ. ~
Q204=+50 ;2-GA BEZPIECZNA WYS. ~
Q301=+1 ;ODJAZD BEZPIECZNY ~
Q365=+1 ;RODZAJ PRZEMIESZCZ.
23 L Z+200 R0 FMAX M9 M6
24 M2
25 LBL 1
26 L X-26 Y+0 RL
27 CR X-23 Y+11 R+20.6 DR-
28 CR X-15 Y+19 R+8 DR+
29 CR X+15 Y+19 R+70.48 DR+
30 CR X+23 Y+11 R+8 DR+
31 CR X+23 Y-11 R+20.6 DR-
32 CR X+15 Y-19 R+8 DR+
33 CR X-15 Y-19 R+70.48 DR+
34 CR X-23 Y-11 R+8 DR+
35 CR X-26 Y+0 R+20.6 DR-
36 L X-40 Y+0
37 LBL 0
38 END PGM kontor MM

Po małych poprawach program działa. Powiedz czy miał robić to co wyszło na mojej symulacji. Zmieniłem cykl 20 na 25 oraz definicję grafiki
0 BEGIN PGM proba MM
1 BLK FORM 0.1 Z X+0 Y+0 Z-50
2 BLK FORM 0.2 X+320 Y+230 Z+0
3 TOOL CALL 13 Z S2000 F120 ;frez_D12
4 CYCL DEF 14.0 GEOMETRIA KONTURU
5 CYCL DEF 14.1 PODPR.KONTURU1
6 CYCL DEF 25 KONTUR OTWARTY ~
Q1=-50 ;GLEBOKOSC FREZOWANIA ~
Q3=+0 ;NADDATEK NA STRONE ~
Q5=+0 ;WSPOLRZEDNE POWIERZ. ~
Q7=+50 ;BEZPIECZNA WYSOKOSC ~
Q10=-1 ;GLEBOKOSC DOSUWU ~
Q11=+150 ;WARTOSC POSUWU WGL. ~
Q12=+500 ;POSUW PRZY ROZWIERC. ~
Q15=+1 ;RODZAJ FREZOWANIA
7 CYCL CALL M3
8 STOP M30
9 LBL 1
10 * - lbl 1 - kontur
11 L X+0 Y+0 F200 M13
12 L Y+130 R0 F220
13 L IX+50 F200
14 L IY+90 F200
15 L IX+100 F200
16 L IY-50 F200
17 L IX+160 F200
18 L IY-100 F200
19 L IX-60 F200
20 L IY-60 F200
21 L IX-250 F200
22 LBL 0
23 END PGM proba MM

Programy znajdują się w ścieżce \iTNC530\tnc w folderze z zainstalowanym symulatorem. Wrzuć program na jakiś hosting a ja go wrzucę u siebie na symulator. Później napisze jak kopiować programy.

[ Dodano: 2012-03-28, 17:53 ]
Odpalamy symulator
Wchodzimy w edycje
PGM MGT do listy programów
Najeżdżamy na program który chcemy skopiować
Wciskamy klawisz F10 na klawiaturze komputera do pojawienia się OKNO na dole symulatora
Wciskamy OKNO (pojawiają się dwie kolumny)
Przechodzimy kursorem na prawą stronę okna
Naciskamy PATH (jeśli nie ma to F9/F10 aż się pojawi)
Wybieramy miejsce zapisu programu
Wciskamy klawisz F9 na klawiaturze komputera aż pojawi się na dole KOPIUJ
Kursorem wracamy na lewą stronę i najeżdżamy na program który chcemy skopiowac
Wciskamy KOPIUJ
Jeśli potrzeba zmieniamy nazwę pliku końcowego (rozszerzenie najlepiej zostawić) i OK
Klikamy OKNO i kopiowanie zakończone.
Analogicznie wgrywamy program na symulator/maszynę.

Jeśli program jest krótki to daj screena. Jeśli dłuższy to instrukcja kopiowania jest gdzieś na forum.

Brak zdefiniowanych narzędzi?
Źle zdefiniowana grafika?
Zła konstrukcja programu?
Możliwości jest wiele. Pokaż przykładowy program który nie działa.